Developer Name(s): Dennis Bricker

Associated User Story/Stories: CPE005-066

ORIGINAL CHMFADR2

CHMFADR2 ;JLR/DEN;UTILITY PROGRAM FOR DOC ID SCREEN;08/20/98 8:16 AM  
 ;;1.0;CHAMPVA SYSTEM;;JULY 4, 1990;Build 3  
 ;V2.0;CALLED FROM CHMF101A;;  
 ;;MODIFIED BY RLC ON 4/13/95 - ADDED OPTION 11) PPR  
 ;;MODIFIED BY RLC ON 4/28/95 - ADDED OPTION 12) PPRs-PDI  
 ;PT 15932 (Y2K)  
 ;JEH 1/8/10 TT 8813 vista application disappeared when inputting data  
 ;JEH 1/8/10 PCDUO 52308 FIX LOGIC ERROR  
 ;KEL 05/04/17 CPE005-007 Add Type of Bill to the EDI Re-open Document ID Screen.   
 ;CFS 08/16/2017 CPE005-004 Add validations and screen changes for CHAMPVA and SB EDI Reopen process.   
 ;HM 09/15/2017 CPE005-034 TOB FC 8 Original PDI Complete initiate reversal  
 ;CFS 10/01/2017 CPD005-069 Add Original and Current PDI Numbers to EDI Manual Re-open Doc ID Screen.  
 ;CFS 10/01/2017 CPE005-073, 074, 075, 076, 077, 079, 080 - Added validations for  
 ; Current and Origanal PDI Number prompts.  
CHKPAG K NP  
 S CHPDIPRL=$$PDITYP^CHMFAUT1(CHMFPDI)  
 Q:CHPDIPRL  
 Q:'$D(^CHMIMAGE(CHMFPDI,1,CHMFPGNM,2,CHMFIMAG))  
 D CLEARB S DX=1,DY=15 X XY S NP=1  
PAG1 X XY W \*7,"Page # ",CHMFPGNM," has already been processed. Do you want to kill the data for this"  
 W !,"page and re-enter it? NO// ",@CHEOL S DY=16,DX=29 X XY D CSBRS^CHSC2  
 S DX=1,DY=15 X XY G:$D(DQOUT) PAG1 I $D(DUOUT) D CLEARB Q  
 I $D(DFOUT) D CLEARB Q  
 S Y=$E(Y,1) S:Y="" Y="N" G:"NY"'[Y PAG1  
 I Y="Y" D OHI K NP,^CHMIMAGE(CHMFPDI,1,CHMFPGNM,2,CHMFIMAG) D OHI  
 Q  
OHI ;  
 ;I $G(CHMFPDI)'="" K ^CHMIMAGE(CHMFPDI,"ZOHI") ;SKD MC284 1-3-07, SKD 2-9-07 REM OUT  
 K OHI,OHIAMT  ;SKD 2-9-07  
 S:$G(DFN)="" DFN=$P($G(^CHMIMAGE(CHMFPDI,1,CHMFPGNM,2,CHMFIMAG,1,0)),U,1) Q:$G(DFN)=""  ;SKD MC284 2-9-07  
 S:$G(BFN)="" BFN=$P($G(^CHMIMAGE(CHMFPDI,1,CHMFPGNM,2,CHMFIMAG,1,0)),U,2) Q:$G(BFN)=""  ;SKD MC284 2-9-07  
 Q:'$G(OHITOS)!('$G(OHIDOS)) ;SKD MC284 2-9-07  
 I $G(CHMFPDI)'="" K ^CHMIMAGE(CHMFPDI,"ZOHI",DFN,BFN,OHITOS,OHIDOS) ;SKD MC284 2-9-07  
 Q  
REDRAW S DY=3,DX=1 X XY W @CHEOL  
 D CLEAR S CHTITLE="DOCUMENT IDENTIFICATION SCREEN",CHSCREEN=""  
 S CHSCREEN=$O(^CHMSCRN("B",CHTITLE,CHSCREEN))  
 D TITLE^CHMFA100,CHOICE^CHMFA100,ERRORS^CHMFA100 Q  
NEWPG D CLEAR,SCREEN Q  
NOPAUS S DX=20,DY=15 X XY  
 W \*7,@CHBON,?20,"CAN'T PAUSE WITHOUT A PDI ASSIGNED !!" Q  
NOCOMM S DX=20,DY=15 X XY  
 W \*7,@CHBON,?13,"You must have a PDI before comments can be entered." Q  
NOSCR S DX=19,DY=15 X XY  
 W \*7,@CHBON,"No Screen for this paticular data entry." Q  
NODATA S DX=18,DY=15 X XY  
 W \*7,@CHBON,"All data must be entered before continuing." Q  
NOSORT S DX=23,DY=15 X XY  
 W \*7,@CHBON,"Data must be entered before sorting." Q  
NOBTCH S DX=10,DY=15 X XY  
 W \*7,@CHBON,"If doing Manual process, a batch number must be entered before",!," using this option. If doing Image processing this option is not allowed."  
 Q  
CLEAR F DY=4:1:20 S DX=1 X XY W @CHEOL  
 Q  
CLEARB F DY=13:1:20 S DX=1 X XY W @CHEOL  
 Q  
FIN S F2=1 Q  
WTOPDI ;CPE005-004 and CPE005-069 Write Original PDI Number for EDI Re-open screens.   
 S DY=5,DX=41 X XY W:$D(CHMOPDI) CHMOPDI W @CHEOL  
 Q  
WTPDI S DY=6,DX=41 X XY W:$D(CHMFPDI) CHMFPDI W @CHEOL  
 I $P(^CHMDIC(741002.21,DUZ,0),"^",10)=0 I $D(CHMFPDI) I CHMFPDI'="" D  
 .;I $D(^CHMIMG(CHMFPDI,"DOC")) D  
 ..S CHMNNUM=$P(^CHMIMG(CHMFPDI,"DOC"),"^",10) S DX=55 X XY  
 ..W:CHMNNUM'="" @CHBON,"(Manual Number: ",CHMNNUM,")",@CHBOFF  
 Q  
WTNP S DY=7,DX=41 X XY W:$D(CHMFNMPG) CHMFNMPG W @CHEOL Q  
WTPG S:'$D(CHMFPGNM) CHMFPGNM=1 S:CHMFPGNM="" CHMFPGNM=1  
 S DY=8,DX=41 X XY W:$D(CHMFPGNM) CHMFPGNM W:$D(CHMFNMPG) " of ",CHMFNMPG W @CHEOL Q  
WTIM Q  
 S:'$D(CHMFIMAG) CHMFIMAG=1 S:CHMFIMAG="" CHMFIMAG=1  
 S DY=9,DX=41 X XY W:$D(CHMFIMAG) CHMFIMAG W @CHEOL Q  
WTTYPE S DY=9,DX=41 X XY I $D(CHMFTYPE),CHMFTYPE'="" S II=0,II=$O(^CHMDIC(741002.08,"B",CHMFTYPE,II)) W $E($P(^CHMDIC(741002.08,II,0),"^",1),1,25)  
 W @CHEOL Q  
QUES S HY=DY,HX=DX G @QU  
1 S DY=14,DX=1 X XY  
 I CHBTCHNO'=0 S X=$$INBTCH^CHMFABU3(CHBTCHNO,CHMFPDI,XY,CHEOL) I 'X S F1=0 Q  
 W !?4,"PDI must be 15 characters long and match the PDI in IMAGE window. The"  
 W !?4,"first 4 digits are Fiscal Year, next 3 are Julian Days, 01-365. The"  
 W !?4,"next 2 digits show the scanner number ('01' or '02'). The rest of the"  
 W !?4,"PDI is a sequential number. An example of a valid PDI is '9106502131313'."  
 G EXIT  
2 S DY=15,DX=22 X XY W "Enter the Number of Pages for this PDI." G EXIT  
3 S DY=15,DX=20 X XY W "Enter the page that is currently displayed." G EXIT  
4 S DY=15,DX=13 X XY W "Enter the image number that is currently displayed" G EXIT  
6 S DY=15,DX=20 X XY W "Enter Type of document or '?' to see a list" G EXIT  
7 D CLEARB S DY=15,DX=8 X XY W "Enter the 'Original PDI Number' based on the business rules." G EXIT  ;CPE005-004  
8 D CLEARB S DY=15,DX=8 X XY W "Enter the 'Original PDI Number' based on the business rules." G EXIT  ;CPE005-069  
9 D CLEARB S DY=15,DX=8 X XY W "Enter the 'Current PDI Number' based on the business rules." G EXIT  ;CPE005-069  
EXIT S DY=HY,DX=HX Q  
CHECK K F1 D CLEARB S LINE="CHK"\_QU G @LINE  
CHK1 D MANUAL  
 I '$D(CHMFPDI) S F1=1 Q  ;JEH 1/8/10 TT 8813  
 I $G(CHMFPDI)="" S F1=1 Q  ;JEH 1/8/10 PCDUO 52308  
 I '$D(CHHAND) S $P(^CHMIMG(CHMFPDI,0),"^",17)=2 S $P(^CHMIMAGE(CHMFPDI,0),"^",8)=2 S X=$$INBTCH^CHMFABU3(CHBTCHNO,CHMFPDI,XY,CHEOL) S:'X F1=0,CHMFPDI="",CHMNNUM="",$P(^CHMDIC(741002.21,DUZ,0),"^",5)="",$P(^CHMDIC(741002.21,DUZ,0),"^",2)="" Q  ; Null subscript on 8/1/05  
 K CHMNNUM S CHMFNMPG=""  
 I PDI I $D(^CHMIMG(PDI,0)) I $P(^(0),"^",6)>2 D ERR1 S F1=1 Q  
 I (Y'?13N)&(Y'?9N)&(Y'?15N) D QUES S F1=1 Q  
 I $D(^CHMIMPB("C",Y)) I $D(CHBTCHNO) I CHBTCHNO=0 D INBAT S F1=1 Q  
 I $D(^CHMIMG("READY",Y)) I $D(CHBTCHNO) I CHBTCHNO=0 D READY S F1=1 Q  
 ; Y2K changes - Commented out per Jim Richardson  
 ;D NOW^%DTC S YR1=$E(%,2,3),YR2=$E(Y,1,2) I YR2>YR1 D QUES S F1=1 Q  
 ;I YR1-1>YR2 D QUES S F1=1 Q  
 ;I +$E(Y,3,5)'<366 D QUES S F1=1 Q  
 ;I +$E(Y,3,5)'>0 D QUES S F1=1 Q  
 I CHBTCHNO'=0 S X=$$INBTCH^CHMFABU3(CHBTCHNO,CHMFPDI,XY,CHEOL)  
 I 'X I CHBTCHNO'=0 S F1=0 Q  
 S $P(^CHMIMG(CHMFPDI,0),"^",17)=3 ;SET SOME PIECE TO MANUAL MANUAL  
 S $P(^CHMIMAGE(CHMFPDI,0),"^",8)=3  
 S $P(^CHMDIC(741002.21,DUZ,0),"^",5)=CHMFPDI Q  
CHK2 Q:Y=""&(CHMFNMPG'="") I (Y'?1N.N) D QUES S F1=1 Q  
 S CHMFNMPG=Y Q  
CHK3 S:'$D(CHMFPGNM) CHMFPGNM="" Q:Y=""  
 I CHMFNMPG'="UNK" I (Y<1)!(Y'?.N) D QUES S F1=1 Q  
 S:'$D(CHMFPGCT) CHMFPGCT=0 S CHMFPGNM=Y,CHMFPGCT=CHMFPGCT+1 Q  
CHK4 S:'$D(CHMFIMAG) CHMFIMAG="" Q:Y=""  
 I (Y<1)!(Y>7)!(Y'?.N) D QUES S F1=1 Q  
 S CHMFIMAG=Y Q  
CHK6 S:'$D(CHMFTYPE) CHMFTYPE="" Q:Y=""  
 K CHOUT,CHERR S:$D(DQOUT) Y="" S CHPRT=Y  
 D LIST^DIC(741002.08,,".01",,,,CHPRT,,"I $P(^(0),U,3)'=0",,"CHOUT","CHERR")  
 I '$D(CHOUT("DILIST",0)) S DY=10,DX=41 X XY W @CHEOL S F1=1 Q  
 I $P(CHOUT("DILIST",0),"^",1)'>0 S DY=10,DX=41 X XY W @CHEOL S F1=1 Q  
 S DTM=13,DBM=20 X CHMAR S DY=13,DX=1 X XY D DISP Q  
CHK7  ;CPE005-004  
 ;Valdation for "Original" PDI Number for CHAMPVA and SB Re-open.  
 I Y="" S Y="XXXX"  
 S VALOPDI=$$CHKOPDI($G(CHMFPDI),Y,CHOSEN,1) I VALOPDI S F1=1  
 I Y="XXXX" S Y=""  
 Q:$G(F1)=1  
 S CHMOPDI=Y  
 S $P(^CHMDIC(741002.21,DUZ,0),"^",2)=CHMOPDI  
 Q  
 ;  
CHK8  ;CPE005-069  
 ;Valdation for "Original" PDI Number for Manual EDI Re-open.  
 S VALOPDI=$$CHKOPDI($G(CHMFPDI),Y,CHOSEN,1) I VALOPDI S F1=1 Q  
 S CHMOPDI=Y  
 S $P(^CHMDIC(741002.21,DUZ,0),"^",2)=CHMOPDI  
 Q  
 ;  
CHK9  ;CPE005-069  
 ;Valadation for "Current" PDI Number for Manual EDI Re-open.  
 I Y="" S Y="XXXX"  
 S VALOPDI=$$CHKOPDI(Y,$G(CHMOPDI),CHOSEN,1) I VALOPDI S F1=1  
 I Y="XXXX" S Y=""  
 Q:$G(F1)=1  
 S CHMFPDI=Y  
 I CHMFPDI'="" D  
 .S $P(^CHMIMG(CHMFPDI,0),"^",17)=4 S $P(^CHMIMAGE(CHMFPDI,0),"^",8)=4  
 .S $P(^CHMDIC(741002.21,DUZ,0),"^",5)=CHMFPDI  
 .S CHMFPP="SIP" D ^CHMFWK01  
 Q  
 ;  
DISP I $P(CHOUT("DILIST",0),"^",1)=1 D  Q  
 .S CHMFIMTY=CHOUT("DILIST",2,1),CHMFTYPE=CHOUT("DILIST",1,1)  
 S L1=0,CT=0  
DI1 S L1=$O(CHOUT("DILIST",1,L1)) I 'L1 D SELE1 Q  
 S CT=CT+1 W !,L1," ",CHOUT("DILIST",1,L1)  
 S X="" I '(CT#5) I $O(CHOUT("DILIST",1,L1)) D SELE  
 G:X="" DI1  
 S CHMFIMTY=CHOUT("DILIST",2,X)  
 S CHMFTYPE=CHOUT("DILIST",1,X) Q  
SELE S X="" W !!,"Select a number or <RETURN> for more: " R X  
 Q:X=""  G:'$D(CHOUT("DILIST",1,X)) SELE Q  
SELE1 S X="" W !!,"Select a number: " R X  
 Q:X=""  G:'$D(CHOUT("DILIST",1,X)) SELE1  
 S CHMFIMTY=CHOUT("DILIST",2,X)  
 S CHMFTYPE=CHOUT("DILIST",1,X) Q  
MANUAL I $P(^CHMDIC(741002.21,DUZ,0),"^",10)'=0 Q  
 K CHHAND I $D(CHMFPDI) I CHMFPDI'="" K ^CHMIMAGE("LOCK",CHMFPDI) D  
 .I $D(CHMNNUM) S ^CHMIMG("MANUAL",CHMFPDI)="" Q  
 S CHMFPDI=Y  
 S PDI=0,PDI=$O(^CHMIMG("E",Y,PDI)) I 'PDI S CHHAND=1 Q  
 I '$D(^CHMIMG("MANUAL",PDI)) S CHHAND=1 Q  
 S CHMNNUM=Y,Y=PDI,CHMFPDI=PDI,$P(^CHMDIC(741002.21,DUZ,0),"^",5)=CHMFPDI  
 S CHMFNMPG=$P(^CHMIMG(PDI,0),"^",2) K ^CHMIMG("MANUAL",PDI)  
 Q:$ZF(-1,"DISPLAY\_DEVICE")'["LAT"  ;D A1^CHMFPDI Q:$D(CHQUIT)  
 S ZZPDI=CHMFPDI,CHMFPP="SIP" D ^CHMFWK01 Q  
SCREEN I $P(^CHMDIC(741002.21,DUZ,0),"^",10)=0 S DY=5,DX=27 X XY W "Batch Number: " W:$D(CHBTCHNO) CHBTCHNO  
 ;BEGIN CPE005-004  
 N CHOSEN,PDIFNL,NPDI,REVRESP,OPDI  
 S CHOSEN=$P($G(^CHMDIC(741002.21,DUZ,0)),"^",10)  
 I CHOSEN=6!(CHOSEN=7)!(CHOSEN=8) D  ;CPE005-069 add CHOSEN=8 check.  
 .I $G(CHMOPDI)="",CHOSEN'=8 S QU=7 N Y S Y="" D CHECK  
 .S DY=5,DX=20 X XY W "Original PDI Number: " W:$D(CHMOPDI) CHMOPDI  
 .S DY=6,DX=21 X XY W "Current PDI Number: " W:$D(CHMFPDI) CHMFPDI  
 I CHOSEN'=6,CHOSEN'=7,CHOSEN'=8 S DY=6,DX=29 X XY W "PDI Number: " W:$D(CHMFPDI) CHMFPDI  ;CPE005-069 add CHOSEN'=8.  
 ;END CPE005-004  
 I $P(^CHMDIC(741002.21,DUZ,0),"^",10)=1 I $D(CHDOCID) W:CHDOCID'="" "-",CHDOCID  
 ;S CHPDIPRL=$$PDITYP^CHMFAUT1(CHMFPDI)  
 ;D:CHPDIPRL TLPGCNT  
 S DY=7,DX=28 X XY W "Total Pages: " W:$D(CHMFNMPG) CHMFNMPG  
 S DY=8,DX=28 X XY W "Page Number: " W:$D(CHMFPGNM) CHMFPGNM  
 ;S DY=9,DX=27 X XY W "Image Number: " W:$D(CHMFIMAG) CHMFIMAG  
 S DY=9,DX=26 X XY W "Type of Image: " W:$D(CHMFTYPE) $E(CHMFTYPE,1,21)  
 S DY=10,DX=24 X XY W "Image Available: " D IMAGE  
 S DY=11,DX=1 X XY S LN="" S $P(LN,"\_",80)="" W LN  
 I CHOSEN=6!(CHOSEN=7) D  ;CPE005-007  
 . S DY=12,DX=21 X XY W "Type of Bill (TOB): " W $$TOB(CHMFPDI,CHMFPGNM,CHMFIMAG) ; KML - 5/4/17  
REV ;  
 I $G(CHMFPCNM)&($G(CHMFIMAG)) D  
 .I $E(+$$TOB(CHMFPDI,CHMFPGNM,CHMFIMAG),3)=8 D  ;HM 09/15/2017 CPE005-034  
 .. S DY=14,DX=21 X XY W "Do you want to initiate a Reversal? Y/N " ;HM 09/15/2017 CPE005-034  
 .. R REVRESP:$S($D(DTIME):DTIME,1:60) ;HM 09/15/2017 CPE005-034  
 .. S:'$T DTOUT="" S:REVRESP="^^" (DFOUT)="" S:REVRESP="^" (DUOUT)="" ;HM 09/15/2017 CPE005-034  
 .. I REVRESP="Y"!(REVRESP="N") D  ;HM 09/15/2017 CPE005-034  
 ... S NPDI=CHMFPDI  
 ... S OPDI=CHMOPDI  
 ... I REVRESP="Y" D  
 .... S DIE=741000.2,DA=CHMOPDI,DR=".06///11;.22///"\_DT D ^DIE K DIE ;BDB 09/19/2017  
 .... S DIE=741000.2,DA=CHMFPDI,DR=".05///"\_DT\_";.06///4" D ^DIE K DIE ;BDB 09/19/2017  
 .... NEW CHMFPDI,ADDQ  
 .... S CHMFPDI=CHMOPDI  
 .... D SORT^CHFCDUTL  
 .... D QUE1^CHFCDUTL ;queue the bene check and bene calc  
 .... S ADDQ=$$ADD2QUE^CH835TRG(OPDI) ;HM 09/20/2017 CPE005-041  
 ... I REVRESP="N" S PDIFNL=$$PDIFINAL^CHCSTAT(NPDI,"F0:35"),DIE=741000.2,DA=NPDI,DR=".06///4" D ^DIE K DIE ;HM 09/20/2017 CPE005-041  
 .. E  G REV  
 Q  
 ;   
NOOHI S DY=18,DX=10 X XY  
 W "No Bill Invoice has been enterd to allow entry of OHI Payments."  
 Q  
 ;  
ERR1 S DY=15,DX=5 X XY W \*7,\*7,@CHBON,"This PDI has already been processed!"  
 W " Cannot be modified at this point!",@CHBOFF  
 Q  
 ;  
ERR3 D CLEARB S DY=15,DX=8 X XY  
 W "PDI: ",Y," - has not been Scanned or Manually entered!"  
 W !,?28,"Please verify this PDI number and re-enter." Q   
INBAT D CLEARB S DY=15,DX=13 X XY  
 W "This PDI is not a Manual PDI. Please Re-enter."  
 Q  
 ;  
READY D CLEARB S DY=15,DX=14 X XY  
 W "This PDI is Image processing only. Please Re-enter."  
 Q  
 ;  
PDI15 D CLEARB S DY=15,DX=20 X XY W \*7,@CHBON  
 W "PDI Number must be 15 digits.",@CHBOFF  
 Q  
 ;  
JUL2000 D CLEARB S DY=15,DX=14 X XY W \*7,@CHBON  ;Validation message for Julian Year less than 2000.  
 W "Julian Year must be year 2000 or later.",@CHBOFF  
 Q  
 ;  
JULFUTR D CLEARB S DY=15,DX=14 X XY W \*7,@CHBON  ;Validation message for Julian Year greater than Current Year.  
 W "Julian Year cannot be in the future.",@CHBOFF  
 Q  
JULDAY D CLEARB S DY=15,DX=14 X XY W \*7,@CHBON  ;Validation message for Julian Day.  
 W "Julian Day must be 001 through 366.",@CHBOFF  
 Q  
 ;  
CHPIMSG D CLEARB S DY=15,DX=14 X XY W \*7,@CHBON  ;Validation message for CHAMPVA Program Indicator.  
 W "PDI Program Indicator must be 91, 97(CHAMPVA EDI).",@CHBOFF  
 Q  
SBPIMSG D CLEARB S DY=15,DX=14 X XY W \*7,@CHBON  ;Validation message for Spina Bifida Program Indicator.  
 W "PDI Program Indicator must be 92, 90(SB EDI).",@CHBOFF  
 Q  
 ;  
CHKOPDI(CHMFPDI,CHMOPDI,CHOSEN,WRTMSG) ;CPE005-004   
 ;Validations for Original and Current EDI Re-open PDI Numbers.  
 ;User Stories CPE005-073, 074, 075, 076, 077 and 080 added to validations.  
 ;CHMFPDI = Current PDI Number  
 ;CHMOPDI = Original PDI Number  
 ;CHOSEN = The menu option the user chose from routine driver CHMFADRV.  
 ;WRTMSG = 0 or 1 - 0 does not display message to the screen; 1 does.  
 I $G(CHOSEN)'=6,$G(CHOSEN)'=7,$G(CHOSEN)'=8 Q 0 ;Validations for EDI Re-open only; Menu options "RC", "RS" and "ER".  
 N ALLCOMP,BENE,CURDT,CURYR,DY,DX,ERR,IEN,JDAY,STATUS  
 S CHMFPDI=$G(CHMFPDI),CHMOPDI=$G(CHMOPDI),CHOSEN=$G(CHOSEN),WRTMSG=$G(WRTMSG)  
 S (BENE,ERR)=0  
 I CHOSEN=8,CHMOPDI="" Q 0 ;Allow user to advance to bottom menu at the Original PDI number prompt.  
 I CHOSEN'=8,CHMOPDI'?15N D  Q ERR ;CPE005-004 and 080  
 .I WRTMSG D PDI15  
 .S ERR=1  
 I CHOSEN=8,CHMOPDI'="",CHMOPDI'?15N D  Q ERR  ;CPE005-080  
 .I WRTMSG D PDI15  
 .S ERR=1  
 I CHOSEN=8,CHMFPDI'="",CHMFPDI'?15N D  Q ERR  ;CPE005-080  
 .I WRTMSG D PDI15  
 .S ERR=1  
 I $E(CHMOPDI,1,4)<2000 D  Q ERR  ;CPE005-004 and 078  
 .I WRTMSG D JUL2000  
 .S ERR=1  
 I CHOSEN=8,CHMFPDI'="",$E(CHMFPDI,1,4)<2000 D  Q ERR  ;CPE005-080  
 .I WRTMSG D JUL2000  
 .S ERR=1  
 S CURDT=$$HTE^XLFDT($H,7),CURYR=$E(CURDT,1,4)  
 I $E(CHMOPDI,1,4)>CURYR D  Q ERR  ;CPE005-004 and 073  
 .I WRTMSG D JULFUTR  
 .S ERR=1  
 I CHOSEN=8,CHMFPDI'="",$E(CHMFPDI,1,4)>CURYR D  Q ERR  ;CPE005-073  
 .I WRTMSG D JULFUTR  
 .S ERR=1  
 N X,CHJUL  
 D NOW^%DTC S:'$D(X) X=DT  
 S X=$E(DT,1,3)\_"0000" D H^%DTC S CHJUL=($P($H,",",1)-%H)+1  
 ;S JDAY=$E(CHMOPDI,5,7)  
 I $E(CHMOPDI,5,7)<"001"!($E(CHMOPDI,5,7)>"366") D  Q ERR  ;CPE005-004 and 074  
 .I WRTMSG D JULDAY  
 .S ERR=1  
 I CHOSEN=8,CHMFPDI'="" D  I ERR Q 1 ;CPE005-074  
 .I $E(CHMFPDI,5,7)<"001"!($E(CHMFPDI,5,7)>"366") D   
 ..I WRTMSG D JULDAY  
 ..S ERR=1  
 I CHOSEN=8,CHMOPDI'="",CHMFPDI'="",$E(CHMOPDI,8,9)=91,$E(CHMFPDI,8,9)'=97 D  Q ERR  ;CPE005-075  
 .I WRTMSG D CHPIMSG  
 .S ERR=1  
 I CHOSEN=8,CHMOPDI'="",CHMFPDI'="",$E(CHMOPDI,8,9)=92,$E(CHMFPDI,8,9)'=90 D  Q ERR  ;CPE005-075  
 .I WRTMSG D SBPIMSG  
 .S ERR=1  
 I CHOSEN=6,CHMOPDI'="",$E(CHMOPDI,8,9)'=91 D  Q ERR  ;CPE005-004  
 .I WRTMSG D CHPIMSG  
 .S ERR=1  
 I CHOSEN=7,CHMOPDI'="",$E(CHMOPDI,8,9)'=92 D  Q ERR  ;CPE005-004  
 .I WRTMSG D SBPIMSG  
 .S ERR=1  
 I CHOSEN=8,CHMOPDI'="",$E(CHMOPDI,8,9)'=91,$E(CHMOPDI,8,9)'=92 D  Q ERR  
 .I WRTMSG D  
 ..D CLEARB  
 ..S DY=15,DX=1 X XY W \*7,@CHBON,"Original PDI Program Indicator must be a 91 for CHAMPVA or 92 for Spina Bifida.",@CHBOFF  
 .S ERR=1  
 I CHMOPDI'="",$P($G(^CHMIMG(CHMOPDI,"E-REOPEN")),"^",3)=1 D  Q ERR  ;CPE005-004 and 077  
 .I WRTMSG D   
 ..D CLEARB  
 ..S DY=15,DX=14 X XY W \*7,@CHBON,"PDI Number has already been reopened.",@CHBOFF  
 .S ERR=1  
 I CHMOPDI'="" D  I ERR Q 1 ;CPE005-079  
 .S ALLCOMP=$$CMPCLAIM(CHMOPDI)  
 .I 'ALLCOMP D  ;All claims have been completed. Do not allow furthur processing on Original PDI.  
 ..I WRTMSG D   
 ...D CLEARB  
 ...S DY=15,DX=30 X XY W \*7,@CHBON,"Cannot ReOpen PDI.",@CHBOFF  
 ..S ERR=1  
 I CHOSEN=8 Q 0  
 S BENE=$$CHKBENE(CHMOPDI,CHMFPDI) I 'BENE D  Q ERR  
 . I WRTMSG D  
 .. D CLEARB  
 .. S DY=15,DX=14 X XY W \*7,@CHBON,"Beneficiary does not match - enter the Original PDI Number.",@CHBOFF  
 . S ERR=1  
 Q ERR  
 ;  
CMPCLAIM(PDI) ;Check to see if all associated claims for PDI have been completed.  
              ;If any of the claims have not been completed, then a false value is returned.  
 ;PDI = PDI Number  
 S PDI=$G(PDI)  
 S COMPLETE=1 ;  
 I '$D(^CHMPAY("C",PDI)) Q 0 ;No claims to check so nothing has been completed.  
 S IEN=0 F  S IEN=$O(^CHMPAY("C",PDI,IEN)) Q:'IEN!('COMPLETE) D  
 .S STATUS=$P(^CHMPAY(IEN,0),"^",2)  
 .I STATUS=1!(STATUS=3)!(STATUS=6)!(STATUS=7)!(STATUS=8)!(STATUS=9) S COMPLETE=0  
 Q COMPLETE  
 ;  
CHKBENE(CHMOPDI,CHMFPDI) ;Check beneficiary for validation purposes  
 ;CHMOPDI = Original PDI Number  
 ;CHMFPDI = Current PDI Number  
 N BFN,CURRBEN,D1,D2,DATA0,DATA10,IEN,ORIGBEN,SPONNUM  
 S CHMOPDI=$G(CHMOPDI),CHMFPDI=$G(CHMFPDI)  
 S (ORIGBEN,CURRBEN,IEN)=""  
 I $D(^CHMPAY("C",CHMOPDI)) D  
 .S IEN=$O(^CHMPAY("C",CHMOPDI,""))  
 .S DATA0=^CHMPAY(IEN,0)  
 .S SPONNUM=$P(DATA0,"^",21)  
 .S BFN=$P(DATA0,"^",22)  
 .S ORIGBEN=SPONNUM\_"/"\_BFN  
 I ORIGBEN="" D  
 .S D1="" F  S D1=$O(^CHMIMAGE(CHMOPDI,1,D1)) Q:D1=""  D  
 ..S D2="" F  S D2=$O(^CHMIMAGE(CHMOPDI,1,D1,2,D2)) Q:D2=""  D  
 ...I $D(^CHMIMAGE(CHMOPDI,1,D1,2,D2,10)) D  
 ....S DATA10=^CHMIMAGE(CHMOPDI,1,D1,2,D2,10)  
 ....S SPONNUM=$P(DATA10,"^"),BFN=$P(DATA10,"^",2)  
 ....S ORIGBEN=SPONNUM\_"/"\_BFN  
 S D1="" F  S D1=$O(^CHMIMAGE(CHMFPDI,1,D1)) Q:D1=""  D  
 .S D2="" F  S D2=$O(^CHMIMAGE(CHMFPDI,1,D1,2,D2)) Q:D2=""  D  
 ..I $D(^CHMIMAGE(CHMFPDI,1,D1,2,D2,10)) D  
 ...S DATA10=^CHMIMAGE(CHMFPDI,1,D1,2,D2,10)  
 ...S SPONNUM=$P(DATA10,"^"),BFN=$P(DATA10,"^",2)  
 ...S CURRBEN=SPONNUM\_"/"\_BFN  
 I ORIGBEN=CURRBEN Q 1  
 Q 0  
LOCK S DY=15,DX=1 X XY W !," PDI: ",CHMFPDI," is Currently Being Processed"  
 W !," By Another User, Please Enter a Different PDI."  
 S CHMFPDI="",CHMFNMPG="" Q  
IMAGE S VAL="No"  
 S:'$D(CHMFPDI) CHMFPDI=""  
 I CHMFPDI I $D(^CHMIMG(CHMFPDI,"DOC")) D  
 .S:$P(^CHMIMG(CHMFPDI,"DOC"),"^",3)'="" VAL="Yes"  
 S DY=10,DX=41 X XY W VAL  
 Q  
 ;  
TOB(CHMFPDI,CHMFPGNM,CHMFIMAG) ;CPE005-004  
 ; retrieve Type of Bill and Frequency Code  
 ; input -   
 ; CHMFPDI - PDI ien  
 ; CHMFPGNM - page number ien  
 ; CHMFIMAG - IMAGE ien  
 ; output -  
 ; returns the Type of Bill and Frequency code   
 N CHMFTOB  
 I '$D(CHMFPDI)!('$D(CHMFPGNM))!('$D(CHMFIMAG)) Q "Frequency Code not defined"  
 I '$D(^CHMIMAGE(+CHMFPDI,1,+CHMFPGNM,2,+CHMFIMAG,"VEN")) Q "Frequency Code not defined"  
 S CHMFTOB=$P($G(^CHMIMAGE(CHMFPDI,1,CHMFPGNM,2,CHMFIMAG,"VEN")),"^",7)  
 I $E(CHMFTOB,3)=5 Q CHMFTOB\_" Late Charge Only"  
 I $E(CHMFTOB,3)=6 Q CHMFTOB\_" Adjustment of Prior Claim"  
 I $E(CHMFTOB,3)=7 Q CHMFTOB\_" Replacement of Prior Claim"  
 I $E(CHMFTOB,3)=8 Q CHMFTOB\_" Void / Cancel of Prior Claim"  
 Q $S(CHMFTOB="":"Frequency Code not defined",1:CHMFTOB\_" Frequency Code not defined")  
 ;   
PGCNT Q:'$D(^CHMIMAGE(CHMFPDI,0))  
 S CHMFNMPG=$P(^CHMIMAGE(CHMFPDI,0),"^",2)  
 Q  
 ;   
TLPGCNT Q:'$D(^CHMIMAGE(CHMFPDI,1))  
 S TLPGCT=9999999,TLPGCT=$O(^CHMIMAGE(CHMFPDI,1,TLPGCT),-1)  
 S:TLPGCT="" TLPGCT=1 S CHMFNMPG=TLPGCT K TLPGCT Q  
 ;

Passed XINDEX? (Y / N): N/A